svg.pablopie.xyz

001
002
003
004
005
006
007
008
009
010
011
012
013
014
015
016
017
018
019
020
021
022
023
024
025
026
027
028
029
030
031
032
033
034
035
036
037
038
039
040
041
042
043
044
045
046
047
048
049
050
051
052
053
054
055
056
057
058
059
060
061
062
063
064
065
066
067
068
069
070
071
072
073
074
075
076
077
078
079
080
081
082
083
084
085
086
087
088
089
090
091
092
093
094
095
096
097
098
099
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156

module View exposing (view)

import Types exposing (..)
import Editor exposing (editor)

import Html exposing ( Html
                     , Attribute
                     , div
                     , img
                     , button
                     , a
                     , span
                     , text
                     , h1
                     , header
                     )
import Html.Events exposing (onClick, on)
import Html.Attributes exposing ( id
                                , class
                                , src
                                , href
                                , target
                                , rel
                                , alt
                                , attribute
                                , name
                                )
import Html.Lazy exposing (lazy)
import Accessibility.Landmark exposing (application, region)
import Accessibility.Role exposing (alert)
import Accessibility.Key exposing (onKeyDown, enter)
import Accessibility.Widget exposing (label)
import Browser exposing (Document)
import Json.Decode
import Regex exposing (Regex, Match, replace)


view : Model -> Document Msg
view model =
  { title = "SVG Editor"
  , body =
      case model.load of
        Loading -> 
          []

        Loaded -> 
          [ lazy container model ]
  }

container : Model -> Html Msg
container model =
  div 
    (
      [ id "container", application, label "SVG Editor" ]
      ++ 
      (if valid model.status then [] else [class "error"])
      ++
      (if model.darkModeOn then [ class "dark" ] else [])
    )
    [ display model
    , lazy editor model
    ]

display : Model -> Html Msg
display model =
  div 
    (
      [ id "display"
      , region
      , class (if model.darkModeOn then "dark" else "light") 
      , label "Picture preview"
      ] 
      ++ 
      -- Alert users when the image is invalid
      (if valid model.status then [] else [ alert ])
    )
    [ img 
      [ id "image", src (uri model), loaded model, alt "Input picture" ] 
      []
    , errorIcon
    , button 
        [ onClick Download
        , label "Download file"
        ] 
        [ span [] [ text "Download" ] ]
    , button 
        [ onClick (Upload Requested)
        , label "Upload file"
        ] 
        [ span [] [ text "Upload" ] ]
    , button 
        [ onClick ToggleDarkMode
        , label "Toggle dark mode"
        ] 
        [ span [] [ text (if model.darkModeOn then "Lighter" else "Darker") ] ]
    ]

uri : Model -> String
uri model =
  "data:image/svg+xml;utf8," 
  ++ 
  (replace model.uriEncoder percentEscape model.image)

percentEscape : Match -> String
percentEscape m =
  case m.match of
    "!" -> "%21"
    "#" -> "%23"
    "$" -> "%24"
    "%" -> "%25"
    "&" -> "%26"
    "'" -> "%27"
    "(" -> "%28"
    ")" -> "%29"
    "*" -> "%2A"
    "+" -> "%2B"
    "," -> "%2C"
    "/" -> "%2F"
    ":" -> "%3A"
    ";" -> "%3B"
    "=" -> "%3D"
    "?" -> "%3F"
    "@" -> "%40"
    "[" -> "%5B"
    "]" -> "%5D"
    str -> str

onError : msg -> Attribute msg
onError f = 
  on "error" (Json.Decode.succeed f)

onLoad : msg -> Attribute msg
onLoad f = 
  on "load" (Json.Decode.succeed f)

loaded : Model -> Attribute Msg
loaded model =
  if valid model.status 
    then onError (Validation Invalid) 
    else onLoad (Validation Valid)

valid : Status -> Bool
valid status =
  case status of
    Valid -> 
      True

    Invalid -> 
      False

errorIcon : Html Msg
errorIcon = 
  img 
    [ id "error", src "assets/error.svg", alt "Something Went Wrong" ] 
    []